10 rem  Simple terminal program. Demonstrates how to change baud rate in
20 rem  STOS.  Baud rate researched by Don Smith, The Atarist BBS in
30 rem  Houston, Texas (713-541-9160) (GENIE: DON.SMITH), and the
40 rem  routine for data I/O by Bob Barton, HASTE president, Houston, TX.
50 rem  ====================================================================
60 mode 1
70 menu$ (1)=" File "
80 menu$ (1,1)="  Quit "
90 menu$ (2)=" Baud "
100 menu$ (2,1)="   300 "
110 menu$ (2,2)="  1200 "
120 menu$ (2,3)="  2400 "
130 menu$ (2,4)="  9600 "
140 menu on 
145 rem  ===================================================================
150 rem  Trap 14,15,A,B,C,D,E,F to set RS-232 parameters in STOS
160 rem  It's the same as the XBIOS(15,-1,-1,-1,-1,-1,-1) call in GFA
165 rem  ===================================================================
170 A=-1 : B=-1 : C=-1 : D=-1 : E=-1 : F=-1
180 trap 14,15,A,B,C,D,E,F
185 rem  ===================================================================
190 rem  Assigning values of -1 allows old assignment to remain unchanged.
200 rem  A=Baud Rate  1=9600 4=2400 7=1200 9=300 bps
210 rem  B=Ctrl\      0=No handshake, default after power up
220 rem    Ctrl/      1=XON/XOFF 2=RTS/CTS 3=XON/XOFF & RTS/CTS (not useful)
230 rem  C=UCR-USART Control Register D=RSR-Receiver Status Register
240 rem  E=TSR-Transmitter Status Register F=SCR-Synchronous Character Register
250 rem  The preceeding from page 174 of "Atari ST Internals" from Abacus
255 rem  ===================================================================
260 open #1,"AUX"
270 X=port(#1)
280 on mnbar goto 350,360
290 if X<0 then X=0
300 print chr$(X);
310 K$=inkey$
320 if len(K$)<1 then goto 340
330 print #1,K$;
340 goto 270
350 stop 
360 on mnselect gosub 390,410,430,450
370 trap 14,15,A,-1,-1,-1,-1,-1
380 goto 270
390 A=9
400 return 
410 A=7
420 return 
430 A=4
440 return 
450 A=1
460 return